remove old files
[rpi-open-firmware.git] / arm_chainloader / lib / arm_strlen.s
1 /*
2 * Copyright (c) 2006 Apple Computer, Inc. All rights reserved.
3 *
4 * @APPLE_LICENSE_HEADER_START@
5 *
6 * This file contains Original Code and/or Modifications of Original Code
7 * as defined in and that are subject to the Apple Public Source License
8 * Version 2.0 (the 'License'). You may not use this file except in
9 * compliance with the License. Please obtain a copy of the License at
10 * http://www.opensource.apple.com/apsl/ and read it before using this
11 * file.
12 *
13 * The Original Code and all software distributed under the License are
14 * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
15 * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
16 * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
17 * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
18 * Please see the License for the specific language governing rights and
19 * limitations under the License.
20 *
21 * @APPLE_LICENSE_HEADER_END@
22 */
23
24 .text
25 .align 2
26
27 .globl strlen
28 /* size_t strlen(const char *s); */
29 strlen:
30 /* save the original pointer */
31 mov r12, r0
32
33 /* see if the string is aligned */
34 ands r3, r0, #3
35
36 /* load the first word, address rounded down */
37 bic r0, r0, #3
38 ldr r2, [r0], #4
39
40 /* skip the next part if the string is already aligned */
41 beq Laligned
42
43 Lunaligned:
44 /* unaligned pointer, mask out the bytes that we've read that we should be ignoring */
45 cmp r3, #2
46 orr r2, r2, #0x000000ff
47 orrge r2, r2, #0x0000ff00
48 orrgt r2, r2, #0x00ff0000
49
50 Laligned:
51 /* load 0x01010101 into r1 */
52 mov r1, #0x01
53 orr r1, r1, r1, lsl #8
54 orr r1, r1, r1, lsl #16
55
56 Laligned_loop:
57 /* ((x - 0x01010101) & ~x & 0x80808080) == hasnull(word) */
58 sub r3, r2, r1 /* x - 0x01010101 */
59 bic r3, r3, r2 /* above & ~x */
60 tst r3, r1, lsl #7 /* above & 0x80808080 */
61 ldreq r2, [r0], #4 /* load next word */
62 beq Laligned_loop
63
64 /* we found a nullbyte */
65 /* r0 (ptr) has overshot by up to 4 bytes, so subtract off until we find a nullbyte */
66 sub r0, r0, #1
67 tst r2, #0x000000ff
68 subeq r0, r0, #1
69 tstne r2, #0x0000ff00
70 subeq r0, r0, #1
71 tstne r2, #0x00ff0000
72 subeq r0, r0, #1
73
74 Lexit:
75 /* len = ptr - original pointer */
76 sub r0, r0, r12
77 bx lr
This page took 0.06627 seconds and 4 git commands to generate.